Na}{

File Content: `SNMPv2-CONF.txt`

SNMPv2-CONF DEFINITIONS ::= BEGIN

IMPORTS ObjectName, NotificationName, ObjectSyntax
                                               FROM SNMPv2-SMI;

-- definitions for conformance groups

OBJECT-GROUP MACRO ::=
BEGIN
    TYPE NOTATION ::=
                  ObjectsPart
                  "STATUS" Status
                  "DESCRIPTION" Text
                  ReferPart

    VALUE NOTATION ::=
                  value(VALUE OBJECT IDENTIFIER)

    ObjectsPart ::=
                  "OBJECTS" "{" Objects "}"
    Objects ::=
                  Object
                | Objects "," Object
    Object ::=

                  value(ObjectName)

    Status ::=
                  "current"
                | "deprecated"
                | "obsolete"

    ReferPart ::=
                  "REFERENCE" Text
                | empty

    -- a character string as defined in [2]
    Text ::= value(IA5String)
END

-- more definitions for conformance groups

NOTIFICATION-GROUP MACRO ::=
BEGIN
    TYPE NOTATION ::=
                  NotificationsPart
                  "STATUS" Status
                  "DESCRIPTION" Text
                  ReferPart

    VALUE NOTATION ::=
                  value(VALUE OBJECT IDENTIFIER)

    NotificationsPart ::=
                  "NOTIFICATIONS" "{" Notifications "}"
    Notifications ::=
                  Notification
                | Notifications "," Notification
    Notification ::=
                  value(NotificationName)

    Status ::=
                  "current"
                | "deprecated"
                | "obsolete"

    ReferPart ::=
                  "REFERENCE" Text
                | empty

    -- a character string as defined in [2]
    Text ::= value(IA5String)
END

-- definitions for compliance statements

MODULE-COMPLIANCE MACRO ::=
BEGIN
    TYPE NOTATION ::=
                  "STATUS" Status
                  "DESCRIPTION" Text
                  ReferPart
                  ModulePart

    VALUE NOTATION ::=
                  value(VALUE OBJECT IDENTIFIER)

    Status ::=
                  "current"
                | "deprecated"
                | "obsolete"

    ReferPart ::=
                  "REFERENCE" Text
                | empty

    ModulePart ::=
                  Modules
    Modules ::=
                  Module
                | Modules Module
    Module ::=
                  -- name of module --
                  "MODULE" ModuleName
                  MandatoryPart
                  CompliancePart

    ModuleName ::=
                  -- identifier must start with uppercase letter
                  identifier ModuleIdentifier
                  -- must not be empty unless contained
                  -- in MIB Module
                | empty
    ModuleIdentifier ::=
                  value(OBJECT IDENTIFIER)
                | empty

    MandatoryPart ::=
                  "MANDATORY-GROUPS" "{" Groups "}"
                | empty

    Groups ::=

                  Group
                | Groups "," Group
    Group ::=
                  value(OBJECT IDENTIFIER)

    CompliancePart ::=
                  Compliances
                | empty

    Compliances ::=
                  Compliance
                | Compliances Compliance
    Compliance ::=
                  ComplianceGroup
                | Object

    ComplianceGroup ::=
                  "GROUP" value(OBJECT IDENTIFIER)
                  "DESCRIPTION" Text

    Object ::=
                  "OBJECT" value(ObjectName)
                  SyntaxPart
                  WriteSyntaxPart
                  AccessPart
                  "DESCRIPTION" Text

    -- must be a refinement for object's SYNTAX clause
    SyntaxPart ::= "SYNTAX" Syntax
                | empty

    -- must be a refinement for object's SYNTAX clause
    WriteSyntaxPart ::= "WRITE-SYNTAX" Syntax
                | empty

    Syntax ::=    -- Must be one of the following:
                       -- a base type (or its refinement),
                       -- a textual convention (or its refinement), or
                       -- a BITS pseudo-type
                  type
                | "BITS" "{" NamedBits "}"

    NamedBits ::= NamedBit
                | NamedBits "," NamedBit

    NamedBit ::= identifier "(" number ")" -- number is nonnegative

    AccessPart ::=
                  "MIN-ACCESS" Access
                | empty
    Access ::=
                  "not-accessible"
                | "accessible-for-notify"
                | "read-only"
                | "read-write"
                | "read-create"

    -- a character string as defined in [2]
    Text ::= value(IA5String)
END

-- definitions for capabilities statements

AGENT-CAPABILITIES MACRO ::=
BEGIN
    TYPE NOTATION ::=
                  "PRODUCT-RELEASE" Text
                  "STATUS" Status
                  "DESCRIPTION" Text
                  ReferPart
                  ModulePart

    VALUE NOTATION ::=
                  value(VALUE OBJECT IDENTIFIER)

    Status ::=
                  "current"
                | "obsolete"

    ReferPart ::=
                  "REFERENCE" Text
                | empty

    ModulePart ::=
                  Modules
                | empty
    Modules ::=
                  Module
                | Modules Module
    Module ::=
                  -- name of module --
                  "SUPPORTS" ModuleName
                  "INCLUDES" "{" Groups "}"
                  VariationPart

    ModuleName ::=

                  -- identifier must start with uppercase letter
                  identifier ModuleIdentifier
    ModuleIdentifier ::=
                  value(OBJECT IDENTIFIER)
                | empty

    Groups ::=
                  Group
                | Groups "," Group
    Group ::=
                  value(OBJECT IDENTIFIER)

    VariationPart ::=
                  Variations
                | empty
    Variations ::=
                  Variation
                | Variations Variation

    Variation ::=
                  ObjectVariation
                | NotificationVariation

    NotificationVariation ::=
                  "VARIATION" value(NotificationName)
                  AccessPart
                  "DESCRIPTION" Text

    ObjectVariation ::=
                  "VARIATION" value(ObjectName)
                  SyntaxPart
                  WriteSyntaxPart
                  AccessPart
                  CreationPart
                  DefValPart
                  "DESCRIPTION" Text

    -- must be a refinement for object's SYNTAX clause
    SyntaxPart ::= "SYNTAX" Syntax
                | empty

    WriteSyntaxPart ::= "WRITE-SYNTAX" Syntax
                | empty

    Syntax ::=    -- Must be one of the following:
                       -- a base type (or its refinement),
                       -- a textual convention (or its refinement), or
                       -- a BITS pseudo-type

                  type
                | "BITS" "{" NamedBits "}"

    NamedBits ::= NamedBit
                | NamedBits "," NamedBit

    NamedBit ::= identifier "(" number ")" -- number is nonnegative

    AccessPart ::=
                  "ACCESS" Access
                | empty

    Access ::=
                  "not-implemented"
                -- only "not-implemented" for notifications
                | "accessible-for-notify"
                | "read-only"
                | "read-write"
                | "read-create"
                -- following is for backward-compatibility only
                | "write-only"

    CreationPart ::=
                  "CREATION-REQUIRES" "{" Cells "}"
                | empty
    Cells ::=
                  Cell
                | Cells "," Cell
    Cell ::=
                  value(ObjectName)

    DefValPart ::= "DEFVAL" "{" Defvalue "}"
                | empty

    Defvalue ::=  -- must be valid for the object's syntax
                  -- in this macro's SYNTAX clause, if present,
                  -- or if not, in object's OBJECT-TYPE macro
                  value(ObjectSyntax)
                | "{" BitsValue "}"

    BitsValue ::= BitNames
                | empty

    BitNames ::=  BitName
                | BitNames "," BitName

    BitName ::= identifier

    -- a character string as defined in [2]
    Text ::= value(IA5String)
END

END

Name	Size	Permission
AGENTX-MIB.txt	17455 bytes	0644
BRIDGE-MIB.txt	50948 bytes	0644
DISMAN-EVENT-MIB.txt	68104 bytes	0644
DISMAN-SCHEDULE-MIB.txt	24613 bytes	0644
DISMAN-SCRIPT-MIB.txt	64311 bytes	0644
EtherLike-MIB.txt	84492 bytes	0644
HCNUM-TC.txt	4660 bytes	0644
HOST-RESOURCES-MIB.txt	52544 bytes	0644
HOST-RESOURCES-TYPES.txt	10583 bytes	0644
IANA-ADDRESS-FAMILY-NUMBERS-MIB.txt	6713 bytes	0644
IANA-LANGUAGE-MIB.txt	4387 bytes	0644
IANA-RTPROTO-MIB.txt	4098 bytes	0644
IANAifType-MIB.txt	35384 bytes	0644
IF-INVERTED-STACK-MIB.txt	5066 bytes	0644
IF-MIB.txt	71691 bytes	0644
INET-ADDRESS-MIB.txt	16782 bytes	0644
IP-FORWARD-MIB.txt	46286 bytes	0644
IP-MIB.txt	185667 bytes	0644
IPV6-FLOW-LABEL-MIB.txt	2028 bytes	0644
IPV6-ICMP-MIB.txt	21057 bytes	0644
IPV6-MIB.txt	56463 bytes	0644
IPV6-TC.txt	3154 bytes	0644
IPV6-TCP-MIB.txt	8858 bytes	0644
IPV6-UDP-MIB.txt	5698 bytes	0644
LM-SENSORS-MIB.txt	5931 bytes	0644
MTA-MIB.txt	42375 bytes	0644
NET-SNMP-AGENT-MIB.txt	15901 bytes	0644
NET-SNMP-EXAMPLES-MIB.txt	9160 bytes	0644
NET-SNMP-EXTEND-MIB.txt	9326 bytes	0644
NET-SNMP-MIB.txt	2036 bytes	0644
NET-SNMP-PASS-MIB.txt	3730 bytes	0644
NET-SNMP-TC.txt	4814 bytes	0644
NETWORK-SERVICES-MIB.txt	21006 bytes	0644
NOTIFICATION-LOG-MIB.txt	24694 bytes	0644
RFC-1215.txt	1174 bytes	0644
RFC1155-SMI.txt	3067 bytes	0644
RFC1213-MIB.txt	79667 bytes	0644
RMON-MIB.txt	147822 bytes	0644
SCTP-MIB.txt	45323 bytes	0644
SMUX-MIB.txt	4649 bytes	0644
SNMP-COMMUNITY-MIB.txt	15490 bytes	0644
SNMP-FRAMEWORK-MIB.txt	22342 bytes	0644
SNMP-MPD-MIB.txt	5496 bytes	0644
SNMP-NOTIFICATION-MIB.txt	20014 bytes	0644
SNMP-PROXY-MIB.txt	9106 bytes	0644
SNMP-TARGET-MIB.txt	22769 bytes	0644
SNMP-TLS-TM-MIB.txt	43927 bytes	0644
SNMP-TSM-MIB.txt	8912 bytes	0644
SNMP-USER-BASED-SM-MIB.txt	39201 bytes	0644
SNMP-USM-AES-MIB.txt	2205 bytes	0644
SNMP-USM-DH-OBJECTS-MIB.txt	21101 bytes	0644
SNMP-USM-HMAC-SHA2-MIB.txt	4400 bytes	0644
SNMP-VIEW-BASED-ACM-MIB.txt	34162 bytes	0644
SNMPv2-CONF.txt	8263 bytes	0644
SNMPv2-MIB.txt	29305 bytes	0644
SNMPv2-SMI.txt	8924 bytes	0644
SNMPv2-TC.txt	38034 bytes	0644
SNMPv2-TM.txt	5775 bytes	0644
TCP-MIB.txt	28564 bytes	0644
TRANSPORT-ADDRESS-MIB.txt	16418 bytes	0644
TUNNEL-MIB.txt	27826 bytes	0644
UCD-DEMO-MIB.txt	2163 bytes	0644
UCD-DISKIO-MIB.txt	4965 bytes	0644
UCD-DLMOD-MIB.txt	3087 bytes	0644
UCD-IPFWACC-MIB.txt	8118 bytes	0644
UCD-SNMP-MIB.txt	52820 bytes	0644
UDP-MIB.txt	20882 bytes	0644

File Content: SNMPv2-CONF.txt

File Content: `SNMPv2-CONF.txt`